Adobe Flash Seit Flash 8 Konvertierung kommt Fehlermeldung

[philkan]

Moin Moin,
ich hab seit der konvertierung einer Flash6 Datei in Flash8 mit AS 2.0 ein Problem mit einer Codezeile, was extrem ungut ist, weil ich einfach nicht von selbst dahinter komm was und vorallem wo das Problem wirklich liegt.

Das gibt mir Flash8 als Fehlermeldung aus:

Szene=Szene 1, Ebene=Aktionen, Bild=10:Zeile 19: ']' erwartet
this[obj][clip + i]._x = this[obj][clip add i]._width * i * abstand;

Das ist der komplette Code, vielleicht kommt von euch jemand dahinter, würde mir wirklich etliche Nerven sparen, denn soviele sinds nicht mehr.
Danke im Voraus!!!

meinXML = new XML();
meinXML.ignoreWhite = true;
meinXML.load("playground/bilder.xml");
loadstatus.text = "LADE";
meinXML.onLoad = function(status) {
    if (status) {
        tempxml = meinXML.firstChild.childNodes;
        anzahl = tempxml.length;
        _root.slideBand("container", "bild", 1, 29, 10.0, anzahl, 250, 1, 1.1, 120);
        loadstatus.text = "";
        delete meinXML;
    }
};

function slideBand(obj, clip, tiefe, ziel, speed, bildanzahl, bildbreite, bildnummer, abstand, posY) {
    createEmptyMovieClip(obj, tiefe);
    for (var i = 1; i <= bildanzahl; i++) {
        this[obj].attachMovie(clip, clip + i, i);
        this[obj][clip + i]._x = this[obj][clip add i]._width * i * abstand;
        this[obj][clip + i]._y = posY;
        this[obj][clip + i].bild = i;
        this[obj][clip + i].titel.text = tempxml[i-1].attributes.titel;
        this[obj][clip + i].onRelease = function() {
            bildnummer = this.bild;            
        };
        this[obj][clip + i].mc.loadMovie("playground/picsplay/" + tempxml[i-1].firstChild);
        this[obj][clip + i].balken_mc._xscale = 0
        this[obj][clip + i].onEnterFrame = function() {
            if (this.mc.getBytesLoaded() > 10) {
            this.gesamt = this.mc.getBytesTotal();            
            this.bereits = this.mc.getBytesLoaded();        
            this.prozent = this.bereits*100/this.gesamt;
            this.balken_mc._xscale = this.prozent;
            if (this.prozent == 100) { 
                this.balken_mc._visible = 0;
                delete this.onEnterFrame;
            }
            }
        };
    }
    this[obj].onEnterFrame = function() {        
        this.xdiff = this[clip + bildnummer]._x - ziel;        
        if (this.xdiff != 0) {            
            this.xdiff = this.xdiff / speed;            
            for (var i = 1; i <= bildanzahl; i++) {
                this[clip + i]._x -= this.xdiff;
                if (this[clip + i]._x <= (ziel - bildbreite)) {
                    this[clip + i]._x += bildanzahl * bildbreite * abstand;
                }
            }
        }
    };
}

 

[2nd]

Mach mal folgendes aus der Zeile:

this[obj][clip + i]._x = this[obj][clip + i]._width * i * abstand;

Also "+" statt "add".

2nd

 

[philkan]

danke mine jung!
das wars, tausend dank!!!!

 

[2nd]

Gerne

2nd