Problem mit Growl

Dieses Thema im Forum "Scripting und Automatisierung" wurde erstellt von BassBurgi, 12.08.2006.

  1. BassBurgi

    BassBurgi Thread Starter

    Moinsen Gemeinde!

    AAAAlso, ich hab ein Problem mit Growl. Ich nutz den Thunderbird und habe im Netz ein Script gefunden, das Thunderbird mit Growl verbindet (also wann ne neue Mail kommt...).

    Das "lustige" dabei ist, dass immer wenn eine neue Mail kommt das Adressbuch aufgeht > NERV! ;)
    und außerdem scheint das Script auszusteigen, wenn zwei Mails aufeinmal ankommen. Das Script sieht folgendermaßen aus:


    Code:
    (*
    by Michael Vöhringer [michael (at) voehringer dot net]
    based on the Mail Advanced script from growl (www.growl.info)
    
    to install enter "osascript  /PATH_TO_SCRIPT/growlNotify.scpt" in the Yamb prefereces
    
    Note: If you have problems with unicode characters please install textcommands from http://osaxen.com/files/textcommands1.0.1.html
    *)
    
    to getPictureForEmailAddress(personEmailAddress)
    	tell application "Address Book"
    		try
    			set thePerson to (first person where the value of emails contains personEmailAddress)
    			set thePiccy to image of thePerson
    			return thePiccy
    		end try
    	end tell
    end getPictureForEmailAddress
    
    on run argv
    	tell application "GrowlHelperApp"
    		try
    			tell application "TextCommands"
    				repeat with itemRef in argv
    					set itemRef's contents to convert to unicode itemRef from "utf8"
    				end repeat
    			end tell
    		end try
    		set appName to "Thunderbird Notification Script"
    		set theSubject to item 1 of argv
    		set theSendersName to item 2 of argv
    		set theMessageSize to item 4 of argv as integer
    		
    		if (theSendersName does not contain "<" or theSendersName does not contain ">") then
    			set theSendersAddress to theSendersName
    		else
    			-- Name and email is set, so extraxt the mail address
    			set beginEmail to offset of "<" in theSendersName
    			set beginEmail to beginEmail + 1
    			set endEmail to offset of ">" in theSendersName
    			set endEmail to endEmail - 1
    			
    			set theSendersAddress to text beginEmail thru endEmail of theSendersName
    		end if
    		
    		
    		-- Get picture from address book
    		set thePersonsPicture to my getPictureForEmailAddress(theSendersAddress)
    		
    		-- Format Message
    		if theMessageSize > 1024 and theMessageSize < 1048576 then
    			set theMessageSize to ((theMessageSize / 1024) as integer) & " KB"
    		else if theMessageSize > 1048576 then
    			set theMessageSize to ((theMessageSize / 1048576) as integer) & " MB"
    		else
    			set theMessageSize to theMessageSize & " B"
    		end if
    		
    		set theTitle to "From: " & theSendersName
    		set theMessage to "Subject: " & theSubject & "
    Size: " & theMessageSize
    		
    		-- Show notification
    		set myAllNotesList to {"Mail Received"}
    		register as application appName all notifications myAllNotesList default notifications myAllNotesList icon of application "Thunderbird.app"
    		
    		try
    			notify with name "Mail Received" title theTitle description theMessage application name appName image thePersonsPicture
    		on error the errorMessage -- user without picture in adressbook
    			notify with name "Mail Received" title theTitle description theMessage application name appName icon of application "Thunderbird.app"
    		end try
    	end tell
    end run
    
    Das Script stammt von dieser Seite:
    http://www.voehringer.net/wiki/index.php/Howto:_E-Mail_Eingang_von_Thunderbird_mit_Growl_anzeigen

    Ich bin leider nicht bewandert was AppleScript angeht und möcht nicht einfach in dem Script rumpfuschen!
    Kann mir da einer helfen?? Wär cool!


    Danke schonmal!

    Btw, wo kann man AppleScript lernen? Lohnt sich das, davon Bescheid zu wissen? Ich bin grad am php lernen, also Grundlagen zu Scripten kenn ich schon :)
     
    Zuletzt von einem Moderator bearbeitet: 21.03.2016
  2. BassBurgi

    BassBurgi Thread Starter

    So, hat sich erledigt...

    hab mal mit meinen php-kenntnissen da drin rumgemacht...
    ein paar klammern gesetzt und gut war!

    ich kann das script sehr empfehlen!
     
Die Seite wird geladen...

Diese Seite empfehlen