Podcasts auf der Apple Watch?

[kermitd]

Ich laufe mittlerweile ganz gern ohne Telefon, nur mit der AW und Bluetooth-Kopfhörern über die ich Musik höre. Das macht zwar Spaß und funktioniert super (von der im Vorhinein nötigen umständlichen und quälend langsamen Synchronisierung der Musik zwischen Uhr und iPhone mal abgesehen) aber oft hätte ich stattdessen auch Lust auf Podcasts. Dooferweise kommt die Uhr ja mit keiner solchen Funktion.

Hat jemand trotzdem eine praktikable Methode parat? Der einzige Weg wäre ja dann vermutlich einzelne Folgen als "Musik" in iTunes zu importieren und in eine Wiedergabeliste zu packen die auf die Uhr synchronisiert wird?? Schon irgendwie umständlich.

 

[Rotmütz]

Versuche ich auch schon seit einiger Zeit. Bisher ohne Erfolg. Sogar die als "Musik" von mir umbenannten Podcast werden nicht mit der Cloud synchronisiert und landen deshalb auch nicht in der Wiedergabeliste.

 

[kermitd]

Versuche ich auch schon seit einiger Zeit. Bisher ohne Erfolg. Sogar die als "Musik" von mir umbenannten Podcast werden nicht mit der Cloud synchronisiert und landen deshalb auch nicht in der Wiedergabeliste.

Ja, man muss da etwas tricksen, da die Cloud eine bestimmte Mindestbitrate erwartet und einzelne Stücke von zu langer Dauer ablehnt. Außerdem bietet die AW keine Möglichkeit sich innerhalb von Musikstücken zu bewegen wodurch lange Podcasts ziemlich unhandlich zu benutzen sind und es anscheinend nicht möglich ist zu einer bestimmten Stelle zu springen. Ich habe mir daher jetzt ein Skript geschrieben, dass mir einen in iTunes zuvor heruntergeladenen Podcast wenn ich ihn in der Podcast-Ansicht markiere und dann das Skript ausführe automatisch in "häppchengroße" Stücke von konfigurierbarer Länge neukodiert (z.Z. bei mir 10 Minuten) und der Musikbibliothek hinzufügt. Ich nutze dafür den AAC-Encoder in iTunes, der für "iTunes Plus" konfiguriert sein sollte um mit der Cloud-Bibliothek zu harmonieren. Die einzelnen Teile werden auf der Watch unterbrechungsfrei hintereinander abgespielt.

property podcastEncoderName : "AAC Encoder"
property maxPartDuration : 10 * 60 --> s
property conversionTimeout : 1000 --> s

use application "iTunes"
use scripting additions

set currentSelection to the selection of application "iTunes"
if (count of currentSelection) is 0 then display dialog "Nothing selected."

repeat with anItem in currentSelection
    tell anItem to if its class is file track and its media kind is podcast then
        set {originalDuration, originalStart, originalFinish} to {its duration, its start, its finish}
        try
            set {i, n} to {0, (round (originalDuration / maxPartDuration) rounding up)}
            repeat while i < n
                set newStart to (i * maxPartDuration)
                set its start to newStart
                set newFinish to newStart + maxPartDuration
                if newFinish > originalDuration then set newFinish to originalDuration
                set its finish to newFinish
             
                set previousEncoder to get current encoder
                set current encoder to (get first encoder whose name is podcastEncoderName)
                try
                    with timeout of conversionTimeout seconds
                        tell (convert anItem)'s first item to set its name to (its name & space & (i + 1) & "/" & n)
                    end timeout
                on error e
                    set current encoder to previousEncoder
                    error e
                end try
             
                set current encoder to previousEncoder
                set i to i + 1
            end repeat
        on error e
            try
                set {its start, its finish} to {originalStart, originalFinish}
            end try
            error e
        end try
     
        set {its start, its finish} to {originalStart, originalFinish}
    end if
end repeat

Resultat:

Nachdem das Skript zu Ende gelaufen ist und die Cloud-Bibliothek ihren automatischen Abgleich beendet hat, füge ich die einzelnen Tracks meiner Lauf-Wiedergabeliste hinzu, für die ich auf dem iPhone eingestellt habe, dass sie automatisch mit der AW synchronisiert werden soll. Das iPhone lädt dann automatisch die Dateien aus der Cloud und schiebt sie auf die AW, wenn Telefon+AW am Netz hängen.

Alles in allem natürlich immer noch 'ne umständliche Sache aber für mich denke ich erstmal so praktikabel.

 

[kermitd]

Gut is übrigens zumindest, dass die fürs Hören auf der Uhr am iPhone ausgewählte Wiedergabeliste permanent synchron gehalten wird, also nicht bloß wenn beide Geräte eingesteckt sind (jedenfalls bei Nutzung der iCloud-Bibliothek). Mit eben der Ausnahme, dass neu hinzukommende Lieder erstmal auf der Uhr ausgegraut sind bis die Geräte wieder am Netz hängen und die eigentliche Übertragung beginnen kann. Bedeutet, dass man am Mac oder dem iPhone die Reihenfolge der Titel ändern oder bereits gehörte Folgen löschen kann und das dann mehr oder weniger sofort auch auf der Uhr gespiegelt wird.

edit: Eine 40-Minuten-Unterteilung ist möglicherweise sinnvoller als 10-Minuten-Teile

 

[Rotmütz]

Vielen Dank für den Tipp. Hat wunderbar funktioniert.
(Ich kann auch mit 10 Minuten-Teilen leben.)