Mit AppleScript System Preferences von QuickTime ändern

[fish77]

Hallo

Evt. kann mir ja jemand helfen, ich suche seit Stunden im Web und finde einfach nicht das richtige...

In den Systemeinstellungen gibt es ein "QuickTime" Pane. Dort unter dem Punkt "Streaming" gibt es die Einstellungen "Sofortige Wiedergabe Aktivieren" und falls das eingestellt ist, kann man per Schieberegler die Verzögerung einstellen.

Weiss jemand ob es eine Möglichkeit gibt, per AppleScript die Checkbox von "Sofortige Wiedergabe Aktivieren" zu aktivieren/deaktivieren und falls diese aktiviert ist, die Verzögerung per AppleScript einzustellen.

Soviel habe ich schon:

tell application "System Preferences"
activate
set current pane to pane "com.apple.preference.quicktime"
set .......
quit
end tell

Bin um jede Hilfe oder Hinweise dankbar...

Grüsse Dave

 

[Andi]

...

Hallo fish77,

tell application "System Preferences"
	set current pane to pane "com.apple.preference.quicktime"
	-- System Events für UI Scripting verwenden
	tell application "System Events"
		tell process "System Preferences"
			-- Tab wählen
			click radio button "Streaming" of tab group 1 of window "QuickTime"
			-- Quicktime Streaming-Geschwindigkeit auswählen
			perform action "AXPress" of pop up button 1 of tab group 1 of window "QuickTime"
			pick menu item "Intranet/LAN" of menu of pop up button 1 of tab group 1 of window "QuickTime"
			-- Checkbox prüfen 0/1 und klicken
			if value of checkbox "Sofortige Wiedergabe aktivieren" of tab group 1 of window "QuickTime" = 0 then
				click checkbox "Sofortige Wiedergabe aktivieren" of tab group 1 of window "QuickTime"
			end if
			-- Schieberegler bedienen 0-100
			set value of slider 1 of tab group 1 of window "QuickTime" to 10
		end tell
	end tell
end tell

Gruß Andi

 

[fish77]

WOW!!!! Andi, ich sag nur TAUSEND DANK!!!

Ein super Osterngeschenk!

Gruss Dave