Mehrere PDF-Dateien (auf dem Desktop) ausdrucken und danach in Ordner verschieben

N

NetMassai

Neues Mitglied
Thread Starter
Dabei seit
20.10.2004
Beiträge
6
Reaktionspunkte
0
Hallo Leute

Als absoluter Programmierneuling habe ich versucht vorgenannten Ablauf zu automatisieren - was mir leider nicht ganz gelungen ist.

Hier meine Automator Aktionen:

1. Finder-Objekte suchen (Name enthält XY)
2. Finder-Objekte öffnen (default application = Vorschau)
3. Finder-Objekte drucken (Standarddrucker)
4. Programm beenden (Vorschau)
5. Finder-Objekte bewegen

Der Arbeitsablauf läuft durch. Bei jedem Zwischenschritt erscheint das grüne Gutzeichen, die PDF's landen am Schluss im gewünschten Ordner, jedoch wird nichts ausgedruckt. Was mache ich falsch?

Vielen Dank für Eure Hilfe und eine schöne Weihnachtszeit!
 
Hallo NetMassai,

Falls Du Mac OS X 10.5 auf Deinem Rechner installiert hast, dann kannst Du auch folgenden Code nutzen, den Du nur leicht an Deine eigene Umgebung anpassen musst (siehe Ordernamen und PDF-Suche).

Er basiert auf Spotlight und mehreren Kommandozeilen-Befehlen und funktioniert komplett im Hintergrund, keine Applikationen schieben sich störend in den Vordergrund.

Bitte zuerst das Skript an Beispieldateien testen.

Code: 
on run
	try
		-- Suchen nach PDF-Dateien auf dem Desktop (inkl. Unterordner),
		-- welche die Zeichenkette «job» enthalten
		set pdffolder to "/Users/martin/Desktop/"
		set findcommand to "mdfind -onlyin " & quoted form of pdffolder & " 'kMDItemContentType == \"com.adobe.pdf\" && kMDItemFSName == \"*job*\"'"
		set pdfpaths to paragraphs of (do shell script findcommand)
		
		-- Ausdrucken der PDF-Dateien mit dem «lp»-Befehl,
		-- verschieben mit dem «ditto»-Befehl,
		-- löschen mit dem «rm»-Befehl
		set destfolder to "/Users/martin/Desktop/PDF/"
		repeat with pdfpath in pdfpaths
			set printcommand to "lp " & quoted form of pdfpath
			do shell script printcommand
			set movecommand to "ditto " & quoted form of pdfpath & " " & quoted form of destfolder
			do shell script movecommand
			set removecommand to "rm " & quoted form of pdfpath
			do shell script removecommand
		end repeat
	on error errmsg number errnum
		tell me
			activate
			display dialog "Ein Fehler ist aufgetreten:" & return & return & errmsg & return & "(" & errnum & ")" buttons {"OK"} default button 1 with icon stop giving up after 20
		end tell
	end try
end run

Beste Grüße aus dem verschneiten Lipperland!
 
Hallo Martin Michel

Super! Dein Script funzt nach dem Anpassen wunderbar und nimmt mir so eine lästige Routinearbeit ab . Vielen Dank!

Grüsse aus der a....kalten Schweiz!
 
Zurück
Oben Unten