Illustrator CS3 - Batch EPS Konvertierung

[little_pixel]

Hallo zusammen,

ich habe eine frage bezüglich EPS und Illustrator CS3:

Ich habe ganz viele EPS Dateien, die mit einer alten Version erstellt wurden.
Diese sollen einfach neu gesichert werden. Mit den Einstellungen, wie im Anhang angegeben.

Scheinbar gibt es keine Möglichkeit diese vielen Dateien auf einmal zu konvertieren.
Wie würdet ihr das vornehmen? Gibt es da ein Tool, das dieses kann? (darf ruhig kostenpflichtig sein ;-)

Vielen Dank für Infos.

PS: Ich habe leider keine Ahnung von der Materie, deshalb brauche ich Rat.

 

[little_pixel]

Mag es mir niemand verraten? ;-)

Gut, hier die Lösung:

-- Hole den Prozessnamen
try
	tell application "System Events" to set processName to (first item of (every process whose name contains "Illustrator"))
	processName
on error
	display alert "Achtung" as warning message "Adobe Illustrator ist nicht geöffent. Bitte starten."
	return
end try


-- alle EPS-Dateien suchen
set allFiles to paragraphs in (do shell script "find " & quoted form of POSIX path of (choose folder with prompt "Bitte wähle den Mutterordner, der die zu konvertierenden EPS Dateien enthält:") & " -iname \"*.eps\"")


-- Wurden Daten gefunden?
if ((count of allFiles) is 0) then
	display alert "Achtung" as warning message "In diesem Ordner befinden sich keine EPS-Dateien."
	return
end if


-- Dateien abarbeiten
repeat with nFile in allFiles
	my runConvertEPS(nFile)
end repeat


--
-- Sub-Functions
--


-- Konvertieren
on runConvertEPS(nFile)
	tell application "Adobe Illustrator"
		try
			
			activate
			
			set theCurrentFileLocation to (nFile as POSIX file)
			
			-- Datei öffnen
			open file theCurrentFileLocation with options {update legacy text:true} without dialogs
			
			-- aktuelle Datei
			set theCurrentFile to the current document
			
			-- sichern + überschreiben
			save theCurrentFile in file theCurrentFileLocation with options {class:EPS save options ¬
				, CMYK PostScript:true ¬
				, compatibility:Illustrator 13 ¬
				, embed all fonts:true ¬
				, PostScript:level 2 ¬
				, preview:transparent color TIFF ¬
				, embed linked files:true ¬
				, overprint:preserve ¬
				, include document thumbnails:true}
			
			
			-- schließen
			close theCurrentFile
			
		on error
			
			-- Alle Fenster schließen
			try
				close every document without saving
			end try
			
			-- Fehlerprotokoll schreiben
			tell me to my logErrorByFile(nFile)
			
		end try
	end tell
end runConvertEPS


-- Protokoll sichern
on logErrorByFile(nFile)
	try
		set schreibeInhalt to ((current date) as string) & ": " & nFile & return
		set pfadZuDatei to (path to desktop folder as string) & "EPS Log.txt"
		
		set the pfadZuDatei to the pfadZuDatei as text
		set the offeneDatei to open for access file pfadZuDatei with write permission
		write schreibeInhalt to the offeneDatei starting at eof
		close access the offeneDatei
	on error fehlerMeldung number fehlerNr
		try
			close access file pfadZuDatei
		end try
	end try
end logErrorByFile

Viele Grüße