APPLE SCRIPT/Automator >> UMBENENNEN >> Ordnername als Dateiname übernehmen

[schickolo]

APPLE SCRIPT/Automator --> Dateien in Ordner umbenennen und als Dateiname den Name des Ordners übernehmen und Index hinzufügen!

Hallo und guten morgen!
Falls ich zu blöd war die Suche richtig zu benutzen und es zu meiner Anfrage schon was ähnliches sorry! Ich habe nichts gefunden ausser einer ähnlich gearteten Anfrage von vor ein paar Stunden!


ZUR SACHE:
ich habe ca 700 Ordner mit Bildern.
Diese Bilder sollen allesamt umbenannt werden!
Die Bilder sollen dabei den Namen des Ordners erhalten - mit fortlaufender, zweistelliger Nummer!
--> DIE ORDNER SOLLEN IHREN NAMEN ALSO BEHALTEN!

Beispiel:

IST-ZUSTAND:
Der Ordner hat den Namen: "ABCDE"
Die Bilder in dem Ordner heißen: Pic_a.jpg, Pic_b.jpg, Pic_c.jpg… usw…

SOLL-ZUSTAND:
Der Ordner hat IMMER NOCH den Namen: "ABCDE"
Aber die Bilder heißen jetzt: ABCDE_01.jpg, ABCDE_02.jpg, ABCDE_03.jpg usw….


Was ich also bräuchte wäre ein script, das den jeweiligen ordnernamen abfragt - bzw kopiert, und dann als Dateiname wieder vor einen index/laufende zahl setzt!
So ähnlich wie es in iPhoto funktioniert wenn man Bilder mit dem Albennamen exportiert, oder in der Adobe Bridge - in der man alle Bilder eines Ordners wie den Ordner benenn kann (mit laufender Nummer)
Da es sich bei mir jedoch um ein paar hundert Ordner handelt, kann ich diese unmöglich einzeln in der Bridge batchen - bzw zuerst in iPhoto Im- und dann wieder exportieren…

Für jemand der scripten kann bestimmt nix großes - aber ich kanns nicht! Deshalb suche jetzt schon seit Stunden und finde nichts was mich zum Ziel führt!
Klar habe ich scripte gesehen die Dateien umbenennen, natürlich habe ich auch den schicken automator angetestet… Ich will aber beim umbennenen die Namen von Ordnern übernehmen! - und zwar automatisch für 700 Stück… (sonst kann Ichs ja gleich von Hand in der Bridge machen!)

 

[little_pixel]

tell application "Finder"
	
	set allSel to selection
	
	repeat with nFolder in allSel
		
		if kind of (info for alias (nFolder as text)) is equal to "Ordner" then
			
			set allImages to (files of nFolder whose name extension is in {"tiff", "tif", "jpeg", "jpg", "pic", "pict", "gif", "png"})
			
			if (allImages is not {}) then
				
				set parentFolderName to name of nFolder
				set counter to 0
				
				repeat with nFile in allImages
					set counter to counter + 1
					
					if (counter < 10) then
						set textCounter to "0" & (counter as text)
					else
						set textCounter to counter as text
					end if
					
					
					set name of nFile to parentFolderName & "_" & textCounter & "." & name extension of nFile
					
				end repeat
				
			end if
			
		end if
		
	end repeat
	
end tell

Viele Grüße

 

[schickolo]

Danke!!!

Funktioniert!!!!
Hammer!!!!

 

[JimmyJoe]

Hallo,
wie verändere ich diesen Script sodass die Nummerierung kleiner 10 = 001, kleiner 100 = 011, und kleiner 1000 = 111 umbenennt?

Aktuell wird die Nummerierung so geändert:
01......10......100

 

[JimmyJoe]

Gibt es auch die Möglichkeit über den Automator mehrere Dateien im folgenden Format umzubenennen?
Ordnername = Dateiname #001.xxx

 

[Pill]

Hallo,
das sollte so funktionieren:

tell application "Finder"
    set theFolders to choose folder with multiple selections allowed -- Ordner auswählen
    repeat with aFolder in theFolders
        set theFiles to files of aFolder
        repeat with i from 1 to count theFiles
            set aFile to item i of theFiles
            set countZeros to (count items of ((count theFiles) as string)) - (count items of (i as string)) --Anzahl an Nullen ermitteln
            set zeros to ""
            repeat countZeros times
                set zeros to zeros & "0"
            end repeat
            set newName to name of container of aFile & " #" & zeros & i & "." & name extension of aFile -- neuen Namen festlegen
            set name of aFile to newName -- umbenennen
        end repeat
    end repeat
end tell

 

[JimmyJoe]

Super gut, Vielen Dank

 

[JimmyJoe]

Gibt es auch die Möglichkeit den Script direkt ( zb. durch einen Button ) in den Finder zu integrieren?