UMTS/GPRS-Karte ohne Provider-Software betreiben

Diskutiere mit über: UMTS/GPRS-Karte ohne Provider-Software betreiben im Internet- und Netzwerk-Hardware Forum

  1. Manjo

    Manjo Thread Starter MacUser Mitglied

    Beiträge:
    903
    Zustimmungen:
    22
    Registriert seit:
    25.07.2005
    Hallo!

    Hier:

    http://www.xs4all.nl/~m10/mac/umtsgprs/manual.html#simplecases

    gibt es ein Modemskript, mit dem man die gängigen UMTS-Karten auch ohne die Hubschrauber-Software der Provider verwenden kann. (Ich weiss nicht, wieso man 9MB benötigt, um ein nichtmal 30kB grosses Modem-Skript zu generieren) Bei meiner Option-Karte funktionierte dieses Skript leider nicht. Und da ich ein zusätzliches Feature benötigte, was die mitgelieferte Software nicht bietet (Beschränkung auf eine Betriebsart UMTS oder GPRS), habe ich mir selbst ein Skript gebastelt. Da es eine Verquickung des o.g. Skripts und des von der Software generierten Skripts ist, sind darauf sicher Urheberrechte, weswegen ich es hier nicht einstellen kann. Aber es gibt eine Anleitung dazu (Vodafone):

    Provider-Software starten
    PIN eingeben und Einstellungen aktivieren
    Systemeinstellungen -> Netzwerk -> Anzeigen: OPTION Globetrotter 3G Quad -> Modem
    Dann im Modem-Skript-Ordner das dort genannte Skript suchen, kopieren und ihm einen Namen geben, der (in meinem Falle) nicht die die Zeichenkombination "MHS" enthält. Sonst wird er u.U. beim nächsten Start der Provider-Software (Fa. Novatel) gelöscht.
    Systemsteuerung schliessen

    Das Einzige, was dem Skript fehlt, ist die PIN Eingabe. Das basteln wir nun dazu. Dabei sind die Nummern der Labels so zu wählen, dass sie fortlaufend an das bestehende Skript angepasst sind. Bei mir war das letzte vorhandene Label 107, also wählte ich 108.

    Die neue Datei editieren:
    Code:
    @ORIGINATE
    wird zu
    Code:
    @ORIGINATE
    ! PIN-Eingabe
    JSR 108
    Am Ende einfügen:
    Code:
    @LABEL 108
    MATCHCLR
    MATCHSTR 20  110 "ERROR\13\10"
    SETTRIES 0
    MATCHSTR 21  115 "+CME ERROR: "
    MATCHSTR 1   114 "+CPIN: READY\13\10"
    MATCHSTR 2   111 "+CPIN: SIM PIN\13\10"
    MATCHSTR 3   123 "+CPIN: SIM PUK\13\10"
    MATCHSTR 4   114 "+CPIN: PH-SIM PIN\13\10"
    MATCHSTR 5   114 "+CPIN: PH-FSIM PIN\13\10"
    MATCHSTR 6   114 "+CPIN: PH-FSIM PUK\13\10"
    MATCHSTR 7   114 "+CPIN: SIM PIN2\13\10"
    MATCHSTR 8   114 "+CPIN: SIM PUK2\13\10"
    MATCHSTR 9   114 "+CPIN: PH-NET PIN\13\10"
    MATCHSTR 10  114 "+CPIN: PH-NET PUK\13\10"
    MATCHSTR 11  114 "+CPIN: PH-NETSUB PIN\13\10"
    MATCHSTR 12  114 "+CPIN: PH-NETSUB PUK\13\10"
    MATCHSTR 13  114 "+CPIN: PH-SP PIN\13\10"
    MATCHSTR 14  114 "+CPIN: PH-SP PUK\13\10"
    MATCHSTR 15  114 "+CPIN: PH-CORP PIN\13\10"
    MATCHSTR 16  114 "+CPIN: PH-CORP PUK\13\10"
    @LABEL 109
    FLUSH
    WRITE "at+cpin?\13\10"
    MATCHREAD 50
    JUMP 122
    @LABEL 110
    IFTRIES 5 116
    INCTRIES
    PAUSE 5
    JUMP 109
    
    @LABEL 111
    ASK 1 "Bitte PINcode eingeben"
    @LABEL 112
    JSR 117    ! PIN senden
    @LABEL 113
    PAUSE 60 ! nach PIN Eingabe erforderlich bei manchen Karten
    @LABEL 114
    RETURN
    
    @LABEL 115
    NOTE "+CME ERROR: "
    JSR 126
    JSR 127
    @LABEL 116
    ASK 2 "Bitte aktivieren Sie das ausfuehrliche Protokoll und versuchen es erneut."
    EXIT -6002
    
    
    @LABEL 117
    MATCHCLR
    MATCHSTR 1 120 "OK\13\10"
    MATCHSTR 2 118 "ERROR\13\10"
    MATCHSTR 3 118 "+CME ERROR: 16\13\10"
    MATCHSTR 4 118 "+CME ERROR: incorrect password\13\10"
    MATCHSTR 5 121 "+CME ERROR: 13\13\10"
    MATCHSTR 6 121 "+CME ERROR: SIM failure\13\10"
    MATCHSTR 7 115 "+CME ERROR: "
    FLUSH
    WRITE "at+cpin=\34^*\34\13\10"
    
    MATCHREAD 50
    JUMP 121
    
    @LABEL 118
    MATCHCLR
    MATCHSTR 1  120 "+CPIN: READY\13\10"
    MATCHSTR 2  119 "+CPIN: SIM PIN\13\10"
    MATCHSTR 3  123 "+CPIN: SIM PUK\13\10"
    MATCHSTR 4  120 "+CPIN: PH-SIM PIN\13\10"
    MATCHSTR 5  120 "+CPIN: PH-FSIM PIN\13\10"
    MATCHSTR 6  120 "+CPIN: PH-FSIM PUK\13\10"
    MATCHSTR 7  120 "+CPIN: SIM PIN2\13\10"
    MATCHSTR 8  120 "+CPIN: SIM PUK2\13\10"
    MATCHSTR 9  120 "+CPIN: PH-NET PIN\13\10"
    MATCHSTR 10 120 "+CPIN: PH-NET PUK\13\10"
    MATCHSTR 11 120 "+CPIN: PH-NETSUB PIN\13\10"
    MATCHSTR 12 120 "+CPIN: PH-NETSUB PUK\13\10"
    MATCHSTR 13 120 "+CPIN: PH-SP PIN\13\10"
    MATCHSTR 14 120 "+CPIN: PH-SP PUK\13\10"
    MATCHSTR 15 120 "+CPIN: PH-CORP PIN\13\10"
    MATCHSTR 16 120 "+CPIN: PH-CORP PUK\13\10"
    MATCHSTR 17 125 "ERROR\13\10"
    MATCHSTR 18 115 "+CME ERROR: "
    FLUSH
    WRITE "at+cpin?\13\10"
    MATCHREAD 50
    JUMP 122
    
    @LABEL 119
    ASK 1 "PIN-Eingabe falsch. Maximal 3 Versuche bis zur Sperrung der Karte!" 124
    JUMP 117
    
    @LABEL 120  ! ok, es kann weitergehen
    RETURN
    
    ! PINcode Fehlerbehandlung
    @LABEL 121
    ASK 2 "121: Fehler bei der PIN-UEbergabe. Die PIN-Eingabe scheint jedoch richtig zu sein."
    JUMP 125
    
    @LABEL 122
    ASK 2 "122: Unbekannter PIN-Code Typ. Die UEbergabe des PIN-Codes an die SIM-Karte kann nicht erfolgen."
    JUMP 125
    @LABEL 123
    ASK 2 "Die SIM-Karte ist gesperrt. In einem normalen Mobiltelefon kann die Karte mit der PUK entsperrt werden."
    JUMP 125
    @LABEL 124
    ASK 2 "PIN-Code falsch. Die Verbindung kann nicht hergestellt werden."
    @LABEL 125
    NOTE "Fehler bei der PIN-UEbergabe" 1
    EXIT -6002
    
    @LABEL 126
    MATCHCLR
    MATCHSTR  1  127 "1"
    MATCHSTR  2  127 "2"
    MATCHSTR  3  127 "3"
    MATCHSTR  4  127 "4"
    MATCHSTR  5  127 "5"
    MATCHSTR  6  127 "6"
    MATCHSTR  7  127 "7"
    MATCHSTR  8  127 "8"
    MATCHSTR  9  127 "9"
    MATCHSTR 10  127 "0"
    MATCHSTR 11  127 "A"
    MATCHSTR 12  127 "B"
    MATCHSTR 13  127 "C"
    MATCHSTR 14  127 "D"
    MATCHSTR 15  127 "E"
    MATCHSTR 16  127 "F"
    MATCHSTR 17  127 "G"
    MATCHSTR 18  127 "H"
    MATCHSTR 19  127 "I"
    MATCHSTR 20  127 "J"
    MATCHSTR 21  127 "K"
    MATCHSTR 22  127 "L"
    MATCHSTR 23  127 "M"
    MATCHSTR 24  127 "N"
    MATCHSTR 25  127 "O"
    MATCHSTR 26  127 "P"
    MATCHSTR 27  127 ","
    MATCHSTR 28  127 "R"
    MATCHSTR 29  127 "S"
    MATCHSTR 30  127 "T"
    MATCHSTR 31  127 "U"
    MATCHSTR 32  127 "\13\10"
    JSR 128
    RETURN
    @LABEL 127
    MATCHREAD 10
    RETURN
    @LABEL 128
    MATCHSTR 33  127 "W"
    MATCHSTR 34  127 "X"
    MATCHSTR 35  127 "Y"
    MATCHSTR 36  127 "Z"
    MATCHSTR 37  127 "\34"
    MATCHSTR 38  127 " "
    MATCHSTR 39  127 "Q"
    MATCHSTR 40  127 ":"
    MATCHSTR 41  127 "a"
    MATCHSTR 42  127 "e"
    MATCHSTR 43  127 "i"
    MATCHSTR 44  127 "o"
    MATCHSTR 45  127 "u"
    MATCHSTR 46  127 "("
    MATCHSTR 47  127 ")"
    MATCHSTR 48  127 "V"
    RETURN
    Wer jetzt noch die Betriebsart der Karte wählen möchte (Nur UMTS, nur GPRS, UMTS bevorzugt, GPRS bevorzugt), suche nach
    Code:
    write "ATV1_OSSYS=1;_OPSYS=3,2;X1\13"
    (entscheidend ist hier die Sequenz "_OPSYS="!) ersetze es durch
    Code:
    write "ATV1_OSSYS=1;_OPSYS=^*,2;X1\13"
    und füge in der Zeile davor folgendes ein:
    Code:
    ASK 2 "Bitte im naechsten Fenster Betriebsart eingeben:\13\13 0: nur GPRS\13 1: nur UMTS\13 2: GPRS bevorzugen\13 3: UMTS bevorzugen"
    ASK 0 "Bitte Betriebsart waehlen: 0 / 1 / 2 / 3"
    
    Es werden 2 Fenster eingeblendet, weil bei "ASK 0" offensichtlich keine mehrzeiligen Texte möglich sind.

    Am Ende noch die Systemsteuerung erneut öffnen und das neue Modemskript auswählen. Fertig. Jetzt kann die Verbindung einfach über "Internet-Verbindung->OPTION Globetrotter 3G Quad->Verbinden" hergestellt werden. Rufnummer, Benutzername und Kennwort wurden ja bereits von der mitgelieferten Software dort eingetragen.

    Ich übernehme keine Garantie. Bei mir funktioniert es jedenfalls prima.

    Viele Grüße,

    Manjo
     
Die Seite wird geladen...
Ähnliche Themen - UMTS GPRS Karte Forum Datum
Suche gutes UMTS / HSDPA Modem.... Internet- und Netzwerk-Hardware 16.10.2011
Vodafone UMTS Stick mit Telekom Sim Card? Internet- und Netzwerk-Hardware 28.07.2011
UMTS-Modem: Empfehlungen Internet- und Netzwerk-Hardware 23.03.2011
Hauwei T-Mobile UMTS Stick mit O2 Blue Sim Karte APN Konfiguration Internet- und Netzwerk-Hardware 01.02.2011
T-Mobile Multimedia Net Card GPRS/UMTS/WLAN Internet- und Netzwerk-Hardware 16.09.2005

Diese Seite empfehlen

Benutzerdefinierte Suche