Itunes CD Covers automatisch importieren ?

Bekehrter · 02.12.2006

Hallo Forum,

leses nach dem Switch Win--> Mac hier schon eine Weile mit,
jetzt mal angemeldet da mir folgendes nicht ganz klar ist:

Itunes bietet ja die Möglichkeit manuell mittels Drag und Drop,
ein Album Cover zu dem aktuell gehörten Album hinzuzufügen.

Ich habe jede Mengen Alben,jeweils mit eigenem Verzeichnis welches neben
den MP3´s auch ein Cover im .jpg Format enthält, auf der Platte.

Da ist manuelles importieren übelst stressig und unkomfortabel

Gibt es eine Option in Itunes, das diese .jpg Datei automatisch als CD Cover
importiert wird ?

Fragende Grüße

Bekehrter

mi00ro · 02.12.2006

hallo,

ob so etwas geht kann ich nicht sagen...

aber einen hinweis auf die funktion "albumcover laden" oben in der menüleiste unter "erweiter" kann ich dir geben, wenn du das nicht gekannt hast.

vielleicht wir ja ein großteil teiner alben erkannt

grüße

Bekehrter · 02.12.2006

Danke für den Tip,
das kenne ich jedoch schon.

Wie schon gesagt, will ich die Covers nicht irgendwo Online ziehen, sondern vorhanden Covers im JPG Format automatisch importieren..

Grüße
Bekehrter

Timosaurier · 02.12.2006

Wo ist das Problem, alle Songs des Albums zu markieren und die jpg draufzuziehen ? Geht doch fix — auch wenn es sich um viele Alben handelt...

Oder hab ich irgendwas falsch verstanden ?

Bekehrter · 02.12.2006

Naja, mach das mal bei > 200 Alben, ist schon irgendwie doof..

Jools · 02.12.2006

Tja hätte das Programm das du unter Windows genutzt hast, die Cover in die mp3 eingebettet hättest du das Problem nicht. Also einmal ran an die Arbeit und gut is

.

Bekehrter · 02.12.2006

Hmm wenn du mir das Programm, welches dies unter Windows
vollbringt nennst, wäre mir doch sehr geholfen...

Timosaurier · 02.12.2006

Seh ich auch so...
Es ist nunmal ein Bisschen Arbeit, seine Bibliothek anzulegen und zu pflegen, aber wenn es einmal gemacht ist, dann ist es gemacht. Mach jeden Tag ein paar Alben, und Du wirst sehen, dass es schneller geht als Du denkst.

Eine Automatisierungsmöglichkeit wirst Du für diese Aufgabe glaube ich nicht finden.

Jools · 02.12.2006

Bekehrter schrieb:
Hmm wenn du mir das Programm, welches dies unter Windows
vollbringt nennst, wäre mir doch sehr geholfen...

iTunes

, ist jetzt aber zu spät, um die Arbeit kommst du nicht mehr drum herum. Wenn du deine ID3 Tags gut gepflegt hast kannst du die Cover auch im Netz suchen lassen, geht wahrscheinlich schneller.

Bekehrter · 02.12.2006

lol, ne wenn´s da nix gibt, verzichte ich dankend. Bequemlichkeit siegt ;-)

little_pixel · 02.12.2006

Hallo zusammen,

vor Kurzen habe ich einen Thread eröffnet, in dem ich mein Programm vorgestellt habe. Es bietet unter anderem genau die Möglichkeit, wie es der "Bekehrte" sucht. Schade fand ich die geringe Resonanz.

"Eine Automatisierungsmöglichkeit wirst Du für diese Aufgabe glaube ich nicht finden."

Das stimmt, und deshalb habe ich sie umgesetzt.

Anbei zwei ScreenShots.

Leider kann ich aus einem diversen Grund das Programm noch nicht weitergeben. Es wird aber kostenlos zur Verfügung stehen.

Besteht Interesse an einem AppleScript, dass :
- das Cover in dem Albumordner sucht
- ein Ordner Cover anlegt, und es darein verschiebt
- das Cover dann direkt im MP3 speichert

Viele Grüße

Bekehrter · 03.12.2006

Hier Resonanz !

Also von meiner Seite aus besteht in jedem Fall Interesse ;-) PN plz.
Schön das noch jemand diese Funktion vermisst..

i_lp · 03.12.2006

HIERHIERHIER - Ich auch, bitte

little_pixel · 03.12.2006

Hallo zusammen,

bitte nach Eigenbedarf ändern.
Hier das Script:

Code:

(*____________________________________________________________________________________________ erzeugt Cover Ordner und verschiebt *)
on verschiebeCover(sel, coverOrdnerNAme, coverIdentifer, coverSuffix, coverIdentiferBack, coverSuffixBack)
	tell application "iTunes"
		with timeout of 30000 seconds
			repeat with naechterTrack in sel
				set pfadZuTrack to location of naechterTrack
				
				tell application "Finder"
					set parentORdner to (container of item pfadZuTrack) as string
					set parentORdnerEinzel to get name of folder parentORdner
					set pfadZuCoverOrdner to parentORdner & coverOrdnerNAme
					set sucheImParentFolder to alias parentORdner
					
					if exists folder pfadZuCoverOrdner then
						try
							-- Cover Front
							set sucheErgebnis to (items of sucheImParentFolder whose name contains coverIdentifer) as string
							set the name of file sucheErgebnis to parentORdnerEinzel & coverSuffix
							move file (parentORdner & parentORdnerEinzel & coverSuffix) to pfadZuCoverOrdner
						end try
						-- Cover Back
						try
							set sucheErgebnis2 to (items of sucheImParentFolder whose name contains "back.jpg") as string
							set the name of file sucheErgebnis2 to parentORdnerEinzel & "_Cover B.jpg"
							move file (parentORdner & parentORdnerEinzel & "_Cover B.jpg") to pfadZuCoverOrdner
						end try
						
					else
						try
							make new folder at (parentORdner) with properties {name:coverOrdnerNAme}
						end try
						-- Cover Front
						try
							-- Cover Front
							set sucheErgebnis to (items of sucheImParentFolder whose name contains coverIdentifer) as string
							set the name of file sucheErgebnis to parentORdnerEinzel & coverSuffix
							move file (parentORdner & parentORdnerEinzel & coverSuffix) to pfadZuCoverOrdner
						end try
						-- Cover Back
						try
							set sucheErgebnis2 to (items of sucheImParentFolder whose name contains "back.jpg") as string
							set the name of file sucheErgebnis2 to parentORdnerEinzel & "_Cover B.jpg"
							move file (parentORdner & parentORdnerEinzel & "_Cover B.jpg") to pfadZuCoverOrdner
						end try
					end if
				end tell
			end repeat
		end timeout
	end tell
end verschiebeCover
(*____________________________________________________________________________________________ erzeugt Cover Ordner und verschiebt *)
(*____*)
(*____*)
(*____*)
(*____________________________________________________________________________________________ einbinden Bild in Track *)
on coverTrack(sel, coverOrdnerNAme, coverIdentifer, coverSuffix, coverSuffixTemp)
	tell application "iTunes"
		
		with timeout of 30000 seconds
			repeat with naechterTrack in sel
				set pfadZuTrack to location of naechterTrack
				
				tell application "Finder"
					set parentORdner to (container of item pfadZuTrack) as string
					set parentORdnerEinzel to get name of folder parentORdner
					set pfadZuCoverOrdner to parentORdner & coverOrdnerNAme
					set pfadZuCover to pfadZuCoverOrdner & ":" & parentORdnerEinzel & coverSuffix
					set tempBildPfad to pfadZuCoverOrdner & ":" & parentORdnerEinzel & coverSuffixTemp
				end tell
				
				
				
				
				try
					tell application "Image Events"
						launch
						-- open the image file
						set tempBild to open pfadZuCover
						-- save in new file
						save tempBild as PICT in file pfadZuCoverOrdner
						close tempBild
					end tell
					
				on error error_message
					display dialog "Fehler beim konvertieren" with title "CoverYourTunes" buttons {"OK"} default button 1 with icon 1 giving up after 5
				end try
				
				try
					set file_ref to open for access tempBildPfad
					set ott to read file_ref from 513 as picture
					close access file_ref
					set data of artwork 1 of (naechterTrack) to ott
					set ott to ""
				on error m
					try
						beep
						close access file_ref
						set ott to ""
					end try
				end try
				
				
			end repeat
		end timeout
	end tell
end coverTrack
(*____________________________________________________________________________________________ einbinden Bild in Track *)
(*____*)

Bekehrter · 04.12.2006

Hi Little_Pixel,

erstmal Danke für das Sktipt !
Was mir fehlt ist eine kurze Installations / Handling Anweisung.
Ich habe das Skript mal in /USER/LIBARY/ITUNES/SCRIPTS kopiert.

Es ist in ITUNES auch verfügbar, die Ausführung bringt jedoch kein Resultat..

Grüße
Bekehrter

little_pixel · 04.12.2006

Hallo,

ich habe ein kleines Skript mit Oberfläche fertiggestellt.
Lege, wie Du es beschrieben hast in den SkriptOrdner von iTunes.

Ausgangssituation:

[] = Ordner
<> = files

[Albumartist - Albumname]
---------<MP3>
---------<JPG>

ODER

[SamplerName] (=> Albumartist = Albumname)
---------<MP3>
---------<JPG>

Das JPG muss sich im Ordner des Albums befinden.
Die Variable "coverIdentifer" muss einen namensinhalt des Bildes enthalten.
(bei mir ist es "front.jpg")

- Makiere die gewüschten Tracks (am besten ein Album oder alles)
- Rufe das Skript auf
- wähle Umbennenen und Verschieben
---> Das Skitpt gibte dem JPG den Namen Albumartist - Albumname.jpg
---> veschiebt das Cover in [Cover]

- Rufe das Skript auf
- Cover in Tracks einbinden
- Das Cover (jetzt in [Cover]) wird in (!!!) dem MP3 gespeichert

Das Resultat ist eine schöne Coverübersicht in iTunes

Leider ist das alles sehr abstrakt und nicht gerade einfach zu erklären.
Am besten ihr verwendet erst ein paar Testdateien, damit ihr seht was passiert.

Viel Erfolg

Nochmal:
Das Sktipt herunterladen. Entpacken. In den Ordner Libary -> iTunes -> Scripts (nötigenfalls anlegen)

little_pixel · 04.12.2006

Ich habe noch ein paar kleine Funktionen hinzugefügt.

"Tag -> Dateiname" dürfte für viele interessant sein.
Dort könnt ihr "TrackNr - Title", "Artist - Title" usw. auswählen.

Die Files werden auf der HD schön benannt.

Viele Grüße

Bekehrter · 04.12.2006

So, hab´s mal getestet. Das Skript funktioniert sehr gut !
Du hast damit echt ein fehlendes Feature umgesetzt. Thanks!

Was noch genial wäre, hinsichtlich automatisierung und komfort:

- als einzubindendes Jpg sollte das erste im Album Ordner gefundene
jpg verwendet werden.Hintergrund: Nicht alle Cover heissen front.jpg
das führt dann zum Konvertiertungsfehler, wenn kein rename erfolgt.

- Die Dialogschritte könnten gerne automatisch ausgeführt werden.

Traumhaft wäre folgender Ablauf:
Titel markieren, Skript ausführen, Cover ist eingebunden, fertig.

Grüße
Betatester Bekehrter ;-)

little_pixel · 04.12.2006

Hallo,

na den Gefallen werde ich Dir noch tun ;-)
Wie gesagt das ist "nur" das Script in kürzester Form von dem tatsächlichen Programm.

"Du hast damit echt ein fehlendes Feature umgesetzt. Thanks!"

Vielen Dank!
Freut mich das es noch jemand benötigen kann.

Also wie gesagt. Ich entferne Euch noch den Zwischenschritt.

Viele Grüße

little_pixel · 04.12.2006

Hallo,

als Anhang das Script, wie versprochen.
Ein DialogFenster ist leider Pflicht. Schließlich muss man eine Aktion abbrechen können. ;-)

Viel Spass damit.

Viele Grüße

Itunes CD Covers automatisch importieren ?

Neues Mitglied

Aktives Mitglied

Neues Mitglied

Aktives Mitglied

Neues Mitglied

Aktives Mitglied

Neues Mitglied

Aktives Mitglied

Aktives Mitglied

Neues Mitglied

Aktives Mitglied

Anhänge

Neues Mitglied

Aktives Mitglied

Aktives Mitglied

Neues Mitglied

Aktives Mitglied

Aktives Mitglied

Neues Mitglied

Aktives Mitglied

Aktives Mitglied