FileMaker und Adressbuch - brauche dringend Hilfe

[jhsenator]

Hallo
ich möchte aus FileMaker mittels AppleScript das Adressbuch aufrufen und darin dann eine Datenkarte suchen lassen. Das funktioniert bereits mit folgendem Skript:

--Suchbegriff aus FileMaker auslesen
tell application "FileMaker Pro"
tell current record
set derNachname to cell "Nachname"
set derVorname to cell "Vorname"
end tell
end tell

-- Adresskarte im Adressbuch suchen und selektieren
tell application "Address Book"
activate
set selection to every person whose (first name contains derVorname) and (last name contains derNachname)
end tell

Nun möchte ich aber z.B. die in FileMaker im Feld "Telefon geschäftl." abgespeicherte Telefonnummer in eben die ausgesuchte Datenkarte im Adressbuch übertragen. Oder auch umgekehrt aus einem Telefonfeld im Adressbuch die Daten in ein entsprechendes Feld in FileMaker. Ich möchte also nur die eine über das vorstehende Skript ausgesuchte Datenkarte im Adressbuch ansprechen.

Und genau an diesem Problem verzweifle ich seit gestern. Kann mir jemand helfen und sagen wie das Skript zum Einlesen der in einer Skriptvariablen gespeicherten Telefonnummer in das 1. Telefonfeld Arbeit in der betreffenden Datenkarte aussehen muss.

Und umgekehrt mit welchem Skriptbefehl ich aus diesem Feld die Daten auslesen kann um sie dann in FileMaker einzusetzen. ich brauche nur die entsprechenden Skriptbefehle für das Adressbuch. Bei FileMaker habe ich keine Probleme mit dem Skirpt.

Ich bitte dringend um Hilfe !!!

Gruß
Jürgen

 

[w2lab]

Address Book 2 FileMaker

set diegeschaeftlicheTelefonnr to ""
tell application "FileMaker Pro"
	tell current record
		set derNachname to cell "derNachname"
		set derVorname to cell "derVorname"
	end tell
end tell

tell application "Address Book"
	set thePerson to first person whose (first name contains derVorname) and (last name contains derNachname)
	set diegeschaeftlicheTelefonnr to value of first item of (phones of thePerson whose (label contains "Work"))
end tell


try
	tell application "FileMaker Pro"
		tell current record
			set cell "Telefon geschäftl." to diegeschaeftlicheTelefonnr
		end tell
	end tell
end try

FileMaker 2 Address Book

tell application "FileMaker Pro"
	tell current record
		set derNachname to cell "derNachname"
		set derVorname to cell "derVorname"
		set diegeschaeftlicheTelefonnr to cell "Telefon geschäftl."
	end tell
end tell

tell application "Address Book"
	activate
	set thePerson to first person whose (first name contains derVorname) and (last name contains derNachname)
	set thephone to first item of (phones of thePerson whose (label contains "Work"))
	try
		set value of thephone to diegeschaeftlicheTelefonnr
	on error
		make new phone at end of phones of thePerson with properties {label:"Work", value:diegeschaeftlicheTelefonnr}
	end try
end tell

person whose (first name contains derVorname) und (phones of thePerson whose (label contains "Work") können jeweils mehrere Einträge enthalten, darum first item of {}
-- Sie können zum Beispiel auch 10 berufliche Telefonnummer für eine Person im Adressbuch eintragen

 

[jhsenator]

Herzlichen Dank !!!!

Es funktioniert perfekt !!!!

Gruß
Jürgen

 

[maceis]

Edit: kaum gepostet fielen mir die Schuppen von den Augen.
Danke für's Lesen