Email als eml-Datei abspeichern

[KinderReich]

Hallo zusammen,

ich will mit einem einfachen Script die ausgewählte Email als eml-Datei abspeichern. Aber es klappt nicht. Was mache ich falsch? Vielen Dank für jede Hilfe.

Hier mein Script:

tell application "Mail"

    set selectedMessages to selection
    set theMessage to item 1 of selectedMessages
    set theSubject to subject of theMessage

    set fileName to theSubject & ".eml"
    set savePath to POSIX path of "/Users/rene/Downloads/"
    set filePath to savePath & fileName

    save as theMessage in filePath

end tell

 

[ThoRo]

Schau mal hier nach, evtl. hilft das ja weiter:

https://superuser.com/questions/484551/creating-save-as-functionality-to-eml-file-in-applescript

 

[MrChad]

1. Arbeite NICHT in oder mit dem "Downloads" Ordner. Versuche NICHT, im "Downloads" Ordner zu speichern.

Der "Downloads" Ordner steht unter Kontrolle und Überwachung von allerlei dubiosen "Schutz"-Mechanismen. Wir hatten es hier schon mehrfach, dass Sachen da nicht funktionierten. Meldungen gibt es dann keine.

2. Aus einem Skript, was hier seit 2 Jahren gut funktioniert (gekürzt):

using terms from application "Mail"
	on perform mail action with messages these_messages for rule this_rule

		tell application "Mail"
			set this_message to item 1 of these_messages

			-- The folder to save the mail in (must already exist)
			set the eml_folder to ("Macintosh HD:Users:mrchad:Documents:emlDrop:" as Unicode text)

			set theID to ((id of this_message) as string)
			set theSubject to subject of this_message

			set messageSource to source of this_message
			set emlFileName to (theID & ".eml") as string
					
			try
				set emlFile to open for access (eml_folder & emlFileName) with write permission
				write messageSource to emlFile
				close access emlFile
			end try
		end tell
	end perform mail action with messages
end using terms from

Entscheidend ist wohl
(a) die Syntax des Ordnernamen,
(b) die Verwendung der "source" und
(c) die Angabe der "write permission"

 

[KinderReich]

Vielen Dank für die beiden Tipps. Ich habe es mit den Tipps geschafft und das Script läuft bei mir.