Verhalten von F-Tasten über defaults verändern?

[kdomke]

Hallo Forum,

Ich hoffe, hier bei meinem ersten Versuch das richtige Forum getroffen zu haben. Wie auch immer.

Ich würde gerne über ein Script das verhalten der F-Tasten umstellen. Im normalen Arbeitsalltag finde ich die Geschichten wie lauter/leiser, heller/dunkler usw. die standardmäßig auf den Tasten liegen eigentlich ganz praktisch. Bei bestimmten Programmen (Ja, es geht um Spiele) hätte ich gerne die F-Tasten als F-Tasten. Nur ist mir das Umstellen über die Pref-Panel jedesamal natürlcih zu umständlich.

Daher würde ich das gerne per kleinem Script umstellen. Da man ja eigentlich alles mit dem Tool "defaults write ..." einstellen kann, stellt sich mir nur die Frage, auf welchen Wert muss ich zugreifen?

Gibt es einen weg, wie man solche Werte herausfindet?

Optimal wäre natürlich ein script, dass mir das Tastaturverhalten umstellt, das Spiel startet, und nach dem Verlassen des Spiels alles wieder zurück stellt. Das sollte man aber dann auch mit ein bisschen Scripting-Magie auch hinbekommen.

Ich hoffe, ich hab mich klar genug ausgedrückt.

Kristian

 

[kilgor]

Hallo Kristian,

hast du hierzu eine Lösung gefunden? Habe spontan ein ähnliches Problem.

Gruß
Louis

 

[kdomke]

Nee, leider nicht...

 

[Andi]

Hallo kdomke,

defaults write -g com.apple.keyboard.fnState 0
defaults write -g com.apple.keyboard.fnState 1

die Änderungen werden aber erst nach logout und login wirksam...

Gruß Andi

 

[Schandor]

Passt vielleicht nicht ganz hierher, aber vielleicht freut sich jemand darüber:

http://hints.macworld.com/search.ph...=&topic=0&type=stories&results=50&mode=search

Liebe Grüße
Schandor

 

[kdomke]

Mmh, das mit dem Logout/Login ist ja doof, war aber bei "defaults" schon fast zu erwarten.

Muss mal gucken, müsste man nicht mit AppleScript da was drehen können?

 

[kdomke]

Got it!

Muss mal gucken, müsste man nicht mit AppleScript da was drehen können?

Ja, man kann!

Leider sprachabhängig, aber ich habs hier mal für Deutsch und Englisch zusammengefasst. Der Unterschied besteht eigentlich nur in den Zeilen, wo auf die richtige Karteikarte gewechselt wird und die Checkbox angeklickt wird. Den Text ggf. auf den richtigen in der jeweiligen Sprache ändern.

Getestet unter Schneeleo 10.6.7

Englisch:

tell application "System Preferences"
	activate
	set current pane to pane "com.apple.preference.keyboard"
end tell

tell application "System Events"
	-- If we don't have UI Elements enabled, then nothing is really going to work.
	if UI elements enabled then
		tell application process "System Preferences"
			get properties
			
			click radio button "Keyboard" of tab group 1 of window "Keyboard"
			click checkbox "Use all F1, F2, etc. keys as standard function keys" of tab group 1 of window "Keyboard"
		end tell
		tell application "System Preferences" to quit
	else
		-- GUI scripting not enabled.  Display an alert
		tell application "System Preferences"
			activate
			set current pane to pane "com.apple.preference.universalaccess"
			display dialog "UI element scripting is not enabled. Please activate \"Enable access for assistive devices\""
		end tell
	end if
end tell

Deutsch:

tell application "System Preferences"
	activate
	set current pane to pane "com.apple.preference.keyboard"
end tell

tell application "System Events"
	-- If we don't have UI Elements enabled, then nothing is really going to work.
	if UI elements enabled then
		tell application process "System Preferences"
			get properties
			
			click radio button "Tastatur" of tab group 1 of window "Tastatur"
			click checkbox "Die Tasten F1, F2 usw. als Standard-Funktionstasten verwenden" of tab group 1 of window "Tastatur"
		end tell
		tell application "System Preferences" to quit
	else
		-- GUI scripting not enabled.  Display an alert
		tell application "System Preferences"
			activate
			set current pane to pane "com.apple.preference.universalaccess"
			display dialog "UI element scripting is not enabled. Please activate \"Enable access for assistive devices\""
		end tell
	end if
end tell

Dafür muss auf dem Mac allerdings noch UI-Scripting eingeschaltet sein. Wie das geht, steht hier.

Das ganze dann als APP speichern, und glücklich sein!

Wenn ich dann mal wieder mit WoW anfange, finde ich dann raus, wie man das auch noch mit der App verbindet

Danke für den Anstoß zum nachsuchen!

Kristian