Dateien in Ordner kleinschreiben lassen...

[Jörg]

Hi Scripter,
ich habe mir überlegt, daß es vielleicht eine ganz nette Aufgabe für AppleScript sein könnte, alle in einem Ordner befindlichen Dateien von Groß-/Kleinschreibung in Kleinschreibung umzuschreiben. Geht das? Dumme Frage, natürlich geht das, aber wie? Und vor allem: unter OS 9.1?

Wer was weiß, hilf mir bitte. Auf dem Macusertreffen gibts dann ein Bier von mir...


Jörg

 

[Andi]

...

Hi Jörg,

möchtest Du den Dateinamen ändern - oder den Inhalt der Dateien?

... auf einem Bein kann man nicht stehen

Gruß Andi

 

[abgemeldeter Benutzer]

GraficConverter, Mehrfachkonvertierung, Kleinschreibung. Ändert die Dateinamen der ausgewählten Dateien in Kleinbuchstaben.

 

[Jörg]

Mensch, Andi & _ut! Ihr seid ja noch länger unterwegs als ich...

Ich möchte nur die Dateinamen von Groß- auf Kleinschreibung ändern. Kann Grafik-Konverter auch bei Nicht-Bilddateien den Namen ändern?

Dankeschön für die superschnelle Antwort!


Jörg

 

[abgemeldeter Benutzer]

Original geschrieben von Jörg
Ich möchte nur die Dateinamen von Groß- auf Kleinschreibung ändern. Kann Grafik-Konverter auch bei Nicht-Bilddateien den Namen ändern?

Ja, das geht bei allen Dateien, nur nicht bei Ordnern.

 

[Andi]

...

Hallo Jörg,

ich hab mich doch richtig erinnert - son Script gabs/gibts? sogar von Apple.
Habs natürlich ausprobiert und läuft nicht unter X.

Also hab ichs etwas angepasst.

-- Buchstaben in File- und Ordnernamen von groß auf klein und umgekehrt umwandeln
-- ©1998 Sal Soghoian, Apple Computer
-- 2003 modified by Andi@macuser.de for Jörg@macuser.de

tell application "Finder"
	activate
	
	set the_folder to choose folder with prompt "bei dem Sie die Groß- und Kleinschreibung verändern wollen"
	
	display dialog "Buchstaben umwandeln in:" buttons {"Abbrechen", "Großbuchstaben", "Kleinbuchstaben"} default button 3
	set the_case_choice to the button returned of the result
	
	display dialog "Untergeordnete Verzeichnisse beachten?" buttons {"Abbrechen", "Alle Ordner", "Nur diesen Ordner"} default button 3
	if the button returned of the result is "Nur diesen Ordner" then
		set the_list to (every item of the_folder)
	else
		set the_list to (every item of the entire contents of the_folder)
	end if
	repeat with this_item in the_list
		set this_item to the contents of this_item
		set the_name to the name of this_item
		if the_case_choice is "Kleinbuchstaben" then
			set the name of this_item to my change_case_of(the_name, "Kleinbuchstaben")
		else
			set the name of this_item to my change_case_of(the_name, "Großbuchstaben")
		end if
	end repeat
end tell
beep 2

on change_case_of(this_text, this_case)
	if this_case is "Kleinbuchstaben" then
		set the_comparison_string to "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
		set the_source_string to "abcdefghijklmnopqrstuvwxyz"
	else
		set the_comparison_string to "abcdefghijklmnopqrstuvwxyz"
		set the_source_string to "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
	end if
	set the_new_text to ""
	repeat with thisChar in this_text
		set x to the offset of thisChar in the_comparison_string
		if x is not 0 then
			set the_new_text to (the_new_text & character x of the_source_string) as string
		else
			set the_new_text to (the_new_text & thisChar) as string
		end if
	end repeat
	return the_new_text
end change_case_of

Ich hoffe das ist das Richtige für Dich.
Paste das Script in den Script Editor und speichere es als Programm ohne Startdialog
Als kompiliertes Script müsste es auch im Scriptmenü laufen - hab ich aber nicht ausgetestet.

Gruß Andi