Okay, ich hab mal eine Lösung, aber die ist nicht ganz optimal, denn:
1. Das Script akzeptiert nur einen einzigen Kontakt pro VCF, sonst funktionierts nicht. Dafür kannst du dann aber mehrere VCFs auf einmal auf das Script ziehen.
2. Leider gibts ein Problem mit dem Adressbuch: Der User muss jeden VCF-Import per Dialog bestätigen. Das Script holt dann das Adressbuch in den Vordergrund und wartet, bis du OK geklickt hast.
3. Leider gibts
noch ein Problem mit dem Adressbuch: Die Adressbuchanzeige aktualisiert sich erst, wenn man einmal den angezeigten Kontakt gewechselt hat.
So, hoffe du kannst mit den
shortcomings leben.
Code:
on open (list_of_files)
repeat with this_file in list_of_files
my process_me(this_file)
end repeat
end open
on run
set myfile to choose file with prompt "VCard mit eingebettetem Bild-URL auswählen:" invisibles no
my process_me(myfile)
end run
on process_me(myalias)
set mycontent to my extract_text(myalias)
set myurl to my extract_url(mycontent)
set myfile to my download_pic(myurl)
set mypic to my get_tiff(myfile)
do shell script "rm " & (POSIX path of myfile)
tell application "Address Book"
set old_letzter to name of person -1
activate
open myalias
repeat while name of person -1 is old_letzter
delay 0.5
end repeat
-- müssen leider warten, bis der User auf OK klickt
set image of person -1 to mypic
end tell
end process_me
on download_pic(this_url)
-- lädt eine Datei herunter und speichert sie als unsichtbares Temp-File
-- Resultat: Alias zum Temp-File
-- Tipp: Temp-File löschen nicht vergessen!
set olddelim to AppleScript's text item delimiters
set AppleScript's text item delimiters to {"."}
set myfileending to last text item of this_url
set myfilename to ".pictemp_" & (time of (current date)) & "." & myfileending
set AppleScript's text item delimiters to olddelim
do shell script "curl " & this_url & " > ~/" & myfilename
alias ((path to home folder as text) & myfilename)
return result
end download_pic
on extract_text(myalias)
-- Gibt den Text aus einer Datei zurück
set myvcf to myalias
set this_file to open for access myvcf
set this_text to read this_file as text
close access this_file
return this_text
end extract_text
on extract_url(mytext)
-- Sucht nach einem Bild-URL in einem VCF-String
repeat with mycurrentline in paragraphs of mytext
if mycurrentline begins with "PHOTO;URI=" then
set myline to text 11 thru -1 of mycurrentline
end if
end repeat
return myline
end extract_url
on get_tiff(myalias)
-- Gibt die TIFF-Daten aus einer Bilddatei zurück
set myimg to myalias
set img to open for access myimg
set tif to read img as TIFF picture
close access img
return tif
end get_tiff
