Volumen von automount ausschliessen

[Atalantia]

Nützlich gegen Tool Partitionen, die es ab und zu auf USB Sticks und sogar auf Festplatten hat. Wer die nicht gemounted haben will kann das mit diesem AppleScript verhindern.

on open var
    doIt(var)
end open
set var to choose folder multiple selections allowed yes
doIt(var)
on doIt(var)
    repeat with x in var
        tell application "System Events"
            set {kindInfo, nameInfo} to {kind of x, name of x}
        end tell
        if kindInfo ≠ "Volume" then
            display alert "Works with volumes only"
            return
        end if
        display dialog "Suspend automount for " & nameInfo & " ?" with icon 1 with title "Auto mount off."
        do shell script "echo " & ("UUID=" & (do shell script "diskutil info " & quoted form of POSIX path of x & " | grep UUID | awk '{print $3}'") & " none hfs rw,noauto") & " >> /etc/fstab" with administrator privileges
    end repeat
end doIt

 

[Olivetti]

ich würde noch nameInfo kommentiert in die fstab schreiben.

 

[Atalantia]

Ja besser. Wenn sich da mal 27 Volumes ansemmeln, weiss man noch um welche es sich handelt.

on open var
    doIt(var)
end open
set var to choose folder multiple selections allowed yes with prompt "Choose volume(s) to suspend."
doIt(var)
on doIt(var)
    repeat with x in var
        tell application "System Events"
            set {kindInfo, nameInfo} to {kind, name} of x
        end tell
        if kindInfo ≠ "Volume" then
            display alert "Works with volumes only."
            return
        end if
        display dialog "Suspend automount for " & nameInfo & " ?" with icon 1 with title "Auto mount off."
        do shell script "echo " & "'# '" & nameInfo & return & ("UUID=" & (do shell script "diskutil info " & quoted form of POSIX path of x & " | grep UUID | awk '{print $3}'") & " none hfs rw,noauto") & " >> /etc/fstab" with administrator privileges
    end repeat
end doIt

 

[Atalantia]

Update: Der Zeilenumbruch ist jetzt UNIX Konform.

on open var
    doIt(var)
end open
set var to choose folder multiple selections allowed yes with prompt "Choose volume(s) to suspend."
doIt(var)
on doIt(var)
    repeat with x in var
        tell application "System Events"
            set {kindInfo, nameInfo} to {kind, name} of x
        end tell
        if kindInfo ≠ "Volume" then
            display alert "Works with volumes only."
            return
        end if
        display dialog "Requires restart to take effect..." with icon 1 with title "Suspend automount for " & nameInfo
        do shell script "echo '#'" & nameInfo & "'
'" & ("UUID=" & (do shell script "diskutil info " & quoted form of POSIX path of x & " | grep UUID | awk '{print $3}'") & " none hfs rw,noauto") & " >> /etc/fstab" with administrator privileges
    end repeat
end doIt

 

[Atalantia]

Warum ist denn hier das Editieren ausgeschaltet? Na, ganz schlau.

 

[Olivetti]

ich habe meinen #2 auch schon gemeldet, weil ich irgendwas editieren wollte. interessiert nur leider keine alte sau.

dein fstab-schreiben ist auch etwas unorthodox, mit dem verschachtelten do shell script.

do shell script "echo \"# " & nameInfo & "
UUID=$(diskutil info " & quoted form of POSIX path of x & " | grep 'UUID' | awk '{print $3}') none hfs rw,noauto\" >> /etc/fstab" with administrator privileges

 

[Atalantia]

Update:

on open var
    try
        doIt(var as alias)
    on error number ernb
        if ernb = -128 then error number -128
        display alert "Works with only one volumes at the time." as critical
        return
    end try
end open
set var to choose from list (list disks) with prompt "Choose volume to suspend." with title "fstabExcludeVolume"
if var = false then error number -128
doIt(var as alias)

on doIt(var)
    tell application "System Events"
        set {kindInfo, nameInfo} to {kind, name} of var
    end tell
    if kindInfo ≠ "Volume" then
        display alert "Works with volumes only."
        return
    end if
    display dialog "Requires restart to take effect." with icon 1 with title "Suspend automount for " & nameInfo
    do shell script "echo \"# " & nameInfo & "
UUID=$(diskutil info " & quoted form of POSIX path of var & " | grep 'UUID' | awk '{print $3}') none hfs rw,noauto\" >> /etc/fstab" with administrator privileges
end doIt

 

[Olivetti]

normalerweise reicht ein "mount -a" hinterherzuwerfen, das spart das rebooten.