Viele USB-Sticks mit denselben Daten beschreiben, wie?

[simusch]

Hallo

Für eine Pressemappe möchte ich USB-Sticks mit unserem Pressematerial beschreiben. Es handelt sich dabei um wohl 200 Stück...

Gibt es eine Möglichkeit, das ganze aufspielen der Daten möglichst automatisch zu machen?
Meine Wünsche:

- Stick einstecken
- Stick wird umbenannt (FAT-Formatierung)
- Daten werden aus einem Ordner / Image aufgespielt
- Stick wird nach Abschluss ausgeworfen
- Beim einstecken des nächsten Sticks soll der Prozess wieder von vorne beginnen.

Ich habe ein wenig mit einer Automator-Action experimentiert, aber da gibt's nichts passendes.
Eine Ordneraktion auf /Volumes hat im ersten Moment auch nix gemacht (habe versucht bei einer Änderung den Namen aller Volumes auszugeben mittels display dialog, aber nichts ist passiert...)

Ich hoffe, ihr könnt mir da helfen
Natürlich käme auch eine Software in Frage, wenn es dann so etwas geben sollte...

Simu

 

[Rothlicht]

Bitteschön:
http://www.isp-proshop.de/MultiBurn-USB-Stick-Kopierer-CopyBox-Mini-12.html

 

[geronimoTwo]

Dieses PrefPane *könnte* der Trigger sein, der nach dem Einstecken eines USB-Stöpsels deine Automator-Aktion anstösst:

http://www.macupdate.com/app/mac/15188/do-something-when

 

[Pill]

Ich würde das mit launchd mit dem StartOnMount-Key auslösen und die Daten dann von einem vorher erstellten Image mit dd kopieren.

 

[little_pixel]

Simu, ich habe genau das schon mal gebaut!

Ich schaue nachher mal, ob ich das Skript gespeichert habe…

Viele Grüße

 

[simusch]

Danke für eure Tipps!
Ein Freund von mir hat mir nun ein AppleScript geschrieben, welches genau dies macht.

Vorteil: läuft nur, wenn es auch offen und gestartet ist, so wird sicher nichts unerwartetes passieren.

Ich habe ihn gebeten, das Script doch hier zu posten, damit alle etwas davon haben... we will see

Danke für die Hilfe!

Simu

 

[Carl_Hifi]

Danke für eure Tipps!
Ein Freund von mir hat mir nun ein AppleScript geschrieben, welches genau dies macht.

Vorteil: läuft nur, wenn es auch offen und gestartet ist, so wird sicher nichts unerwartetes passieren.

Ich habe ihn gebeten, das Script doch hier zu posten, damit alle etwas davon haben... we will see

Danke für die Hilfe!

Simu

Sorry dass ich den alten Beitrag ausgrabe, aber genau das suche ich! Hast Du das Script irgendwo?

 

[simusch]

Hier meine Variante des Scripts:

property myDisk : "USB DISK" --Name des leeren USB-Sticks
property newDisk : "FIRMA" --Neuer Name
property copyFolder : "FIRMA" --Verzeichnis auf dem Desktop mit zu kopierenden Daten

repeat
   set mountedDisks to paragraphs of (do shell script "/bin/ls /Volumes")
   if myDisk is in mountedDisks then
     log "Stick erkannt!"
     delay 1
     try
       do shell script "/usr/sbin/diskutil eraseVolume MS-DOS '" & newDisk & "' '/Volumes/" & myDisk & "'"
     on error errorMessage number errorNumber
       display alert errorNumber message errorMessage
       beep
       log "Formatieren fehlgeschlagen"
     end try
    
     delay 1
    
     set sourcefolder to (path to desktop as text) & copyFolder
     set destinationfolder to ("/Volumes/" & newDisk & "/" as POSIX file)
    
     try
       tell application "Finder"
         set myFiles to get every item of (entire contents of folder sourcefolder) --whose name does not start with "."
         duplicate myFiles to destinationfolder
        
         -- delete hidden files
         do shell script "rm -fr " & quoted form of POSIX path of "/Volumes/" & newDisk & "/._*"
        
         eject disk newDisk
         log "done."
         say "done"
       end tell
     on error errorMessage number errorNumber
       beep
       display alert errorNumber message errorMessage
     end try
    
   end if
   delay 3
end repeat

Ablauf:
- Daten in einen Ordner mit Namen "FIRMA" auf dem Desktop ablegen
- Script öffnen und starten
- Stick einstecken
- Im Script-Editor sollte unter "Nachrichten" erscheinen: "Stick erkannt!"
- Stick wird formatiert und umbenannt
- Daten werden kopiert
- Nach dem kopieren WARTEN, bis der Stick vom Desktop verschwindet (wenn "done" ertönt)
- Neuen Stick einstecken

Meine Erfahrungen:
- Zwischendurch kam es vor, dass ein Stick nicht korrekt formatiert werden konnte. Da habe ich das Script jeweils gestoppt, Stick entfernt und neu gestartet (war so ca alle 20-40 Sticks der Fall)
- Wenn unter "Nachrichten" nichts erscheint, Script stoppen und neu starten
- Für meine 150MB Daten (570 Dateien einer Offline-Website) dauerte der Vorgang jeweils ca 90 Sekunden
- Ich habe jeweils parallel am iMac und am MacBook gearbeitet, so ging das kopieren rasch

 

[Carl_Hifi]

Danke!!