iCloud Erinnerung mit AS erstellen

[MichaHo]

Hallo,

die Suche hat mir leider keine Ergebnisse gebracht, mit denen ich hätte eine Lösung finden können, daher frage ich hier nach.

Ich möchte per Applescript einen Eintrag in meine iCloud Erinnerungen erstellen, damit ich zu einem bestimmten Zeitpunkt erinnert werde.

Alternativ ginge auch ein Termin mit Bildschirm Erinnerung.

Beides funktioniert leider nicht.

Hier mein Versuch für die Erinnerung:

set theCalendar to "iCloud" -- Kalendername
set checkOut to (current date) + 5400 --Zeitpunkt: jetzt plus 90 Minuten

makeEvent(theCalendar, checkOut) --Ausführung

on makeEvent(theCalendar, checkOut)
	tell application "iCal"
		tell calendar theCalendar
			make new todo at end with properties ¬
				{description:"CheckOut", summary:"CheckOut", due date:checkOut}
		end tell
	end tell
end makeEvent

Da erhalte ich den Fehler, das die iCloud URL keine URL ist, die dieses unterstützt

als nächstes habe ich versucht einen Termin in der iCloud zu erstellen:

set theCalendar to "iCloud" -- Kalendername
set checkOut to (current date) + 5400 --Zeitpunkt: jetzt plus 90 Minuten

makeEvent(theCalendar, checkOut) --Ausführung


on makeEvent(theCalendar, checkOut)
	tell application "iCal"
		activate
		tell calendar theCalendar
			set theCurrentDate to checkOut
			make new event at end with properties ¬
				{description:"CheckOut", summary:"CheckOut", start date:theCurrentDate, end date:theCurrentDate + 5 * minutes}
			set nr to number of event
			set theEvent to event nr
			tell theEvent
				make new display alarm at end with properties {trigger interval:-5}
			end tell
		end tell
		quit
	end tell
end makeEvent

Hier wird zwar der Termin erstellt, aber den Teil mit dem Display Alarm, der wird NICHT hinterlegt.

Man bekommt als NICHT mit, wenn der Termin fällig ist.

Komisch ist, erstelle ich diesen Termin in einem lokalen Kalender, dann wird er zwar richtig erstellt, auch mit display alarm, aber ausgeführt wird er nicht, es erscheint keine Erinnerung.

Was mach ich denn falsch?

Ich möchte lediglich erreichen, das mit einem Script (in dem einige Aktionen ausgeführt werden) automatisch eine Erinnerung (am liebsten in die iCloud) erstellt wird, die mich auch wirklich erinnert!!

Vielleicht hat jemand nen Tip was ich noch versuchen kann.

Vielen Dank

Grüße

Micha

 

[MichaHo]

Hallo,

nach schlaflosen Nächten habe ich nun selbst die Lösung gefunden (eigentlich total simpel und logisch).

Wie sooft ist der einfachste Weg der richtige.....

hier nun mein Script (der Teil der das Event erstellt) für alle die, die vor dem gleichen Problem stehen:

set theDate to (current date) + 240 --Testdatum

iCalEvent("iCloud", theDate) --Übergabe an die Funktion

on iCalEvent(theCal, theDate)
	tell application "iCal"
		activate
		tell calendar theCal
			set theEvent to make new event at end with properties ¬
				{description:"CheckOut", summary:"CheckOut", start date:theDate, end date:theDate + 5 * minutes} --Erstellen des Termins und übergabe an die Variable
			tell theEvent
				make new sound alarm at end with properties {trigger interval:-5} --Nachricht mit Ton
				make new display alarm at end with properties {trigger interval:-5} --Bildschirm Nachricht
				-- Hier können noch mehr Hinweise an den Termin angehängt werden, zBsp. ein anderes Script öffnem
			end tell		
		end tell
	end tell
end iCalEvent

Grüße

Micha