Handbrake+Automator+es werden nach dem Konvertieren keine Dateien gefunden!

[Xptnlmax2]

Wenn du als Preset "Itunes kompatibel" eingibst, dauert das konvertieren bei mir 4 min. (Bei 45 min 720p video)

 

[t3lly]

aber dann konvertiert er nicht "richtig" in h264 oder?

 

[Xptnlmax2]

Auf jeden Fall lässt sich das Video zu iTunes hinzufügen und hat erstklassige qualtität, probiere doch einfach mal aus

 

[t3lly]

ja ich weiß, aber ich brauch schon richtiges h264 für die hardware Dekodierung. Zeit hab ich auch genug. Weiß man denn was hinter Flicks steht? Also mit welcher Technik der konvertiert. Habs jetzt jedenfalls gekauft. Im Appstore ist es teurer als auf deren Page.. das sind ja mal Hanseln. Wahrscheinlich genau 30%.

 

[NiLS-Da-BuBi]

Also ich konvertiere auch mit Handbrake mehrsprachige Serien. Mir hilft da immer im Audiotab der "add all tracks" dann muss man nicht alles einzeln hinzufügen.

Ich nutze iFlicks danach für die Metadaten. Konvertieren macht Handbrake imho besser, auch kann ich da die SRT ordentlich einbinden und es wird eine 5.1 Spur fürs Apple tv angelegt und eine 2.0 Spur für iOS oder Mac.

 

[Tuennes123]

also ich bin mit iVI aus dem Appstore echt zufrieden.
Die Pro Version konvertiert wohl auch DVD's, aber das benötige ich nicht.
Quali ist in meinen Augen absolut ok.
Behält auch alle Spuren und sucht ziemlich zuverlässig die Tags.
BG
Tünnes

 

[Levithan]

Ich habe vor einiger Zeit mal ein solches Script geschrieben und per Automator als Ordner Dienst eingebunden. Das Script durchsucht alle markierten Ordner nach Dateien mit der Endung "avi", "mkv" und "mp4" welche kein Farbflag gesetzt haben und konvertiert die mittels HandbrakeCLI. Anschließend schickt er alle konvertierten Files zu iFlicks (AppStore) um die Videos zu taggen.
Das Script sieht so aus:

on run {input, parameters}
	repeat with curItems in input
		
		set currentFolder to curItems as alias
		
		set convertFlags to " -e x264 -q 20" as string
		set doneFiles to {"#"}
		tell application "System Events"
			set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
		end tell
		tell application "Finder"
			if (kind of currentFolder as string) is "Ordner" or "Folder" then
				set all_Files to (every file of entire contents of currentFolder whose ((name extension is "avi" or name extension is "mp4" or name extension is "mkv") and label index is 0))
				repeat with i from 1 to number of items in all_Files
					try
						if isRunning then
							tell application id "com.Growl.GrowlHelperApp"
								try
									set the allNotificationsList to {"Starte Konvertierung", "Konvertierung beendet", "Fehler"}
									set the enabledNotificationsList to {"Starte Konvertierung", "Konvertierung beendet", "Fehler"}
									register as application ¬
										"ConvertFolder" all notifications allNotificationsList ¬
										default notifications enabledNotificationsList ¬
										icon of application "Script Editor"
								end try
							end tell
						end if
						set currentFile to (item i of all_Files) as alias
						set fileName to (name of currentFile as text)
						set unixPath to POSIX path of currentFile
						if (exists folder "done" of currentFolder) is false then
							set doneFolder to make new folder at currentFolder with properties {name:"done"}
						else
							set doneFolder to (currentFolder & "done" as text) as alias
						end if
						set newFile to ((doneFolder as text) & (name of currentFile as text))
						set newFile to (characters 1 thru -4 of newFile as string) & "m4v"
						set newFileUnix to POSIX path of newFile
						set shellCommand to "nice /Applications/HandBrakeCLI -i " & quoted form of unixPath & " -o " & quoted form of newFileUnix & convertFlags
						
						if isRunning then
							tell application id "com.Growl.GrowlHelperApp"
								try
									notify with name ¬
										"Starte Konvertierung" title ¬
										"Starte Konvertierung" description ¬
										("Konvertiere ") & fileName & " / " & ((number of items in all_Files) - i as text) & " verbleibend" application name "ConvertFolder"
								end try
								do shell script shellCommand
							end tell
						else
							do shell script shellCommand
						end if
						set label index of currentFile to 6
						set end of doneFiles to newFile
					on error errmsg
						beep
						delay 2
						set label index of currentFile to 2
						set the_log to open for access file ((currentFolder as text) & "Error.txt") with write permission
						write errmsg & return to the_log starting at eof
						close access the_log
						if isRunning then
							tell application id "com.Growl.GrowlHelperApp"
								try
									notify with name ¬
										"Fehler" title ¬
										"Fehler" description ¬
										"Fehler in File " & fileName application name "ConvertFolder"
								end try
							end tell
						end if
					end try
				end repeat
				if ((isRunning) and (number of items in all_Files > 1)) then
					tell application id "com.Growl.GrowlHelperApp"
						try
							notify with name ¬
								"Konvertierung beendet" title ¬
								"Konvertierung beendet" description ¬
								"Pumpe " & ((number of items in doneFiles) - 1 as text) & " Files zu iFlicks" application name "ConvertFolder"
						end try
					end tell
				end if
				repeat with i from 2 to number of items in doneFiles
					set currentFile to item i in doneFiles as alias
					tell application "iFlicks"
						import currentFile without gui
					end tell
				end repeat
			end if
		end tell
	end repeat
	return input
end run

Im Automator siehe Screenshot. In der Variablen "convertFlags" kann man einfach die Handbrake Parameter ändern.
Das Script tut seit Monaten gute Dienste Ich hab das komplette Automator File auch mal angehängt, viel Spass damit.

Grüße

 

[gotocuba]

Hi,

im Grunde brauche ich genau dass was hier bei euch beschrieben wird....aber ich komme überhaupt nicht weiter... habe noch nie ein script oder Automator Befehl erteilt... bin am verzweifeln..... kann mir einer helfen.....
Danke

 

[NiLS-Da-BuBi]

Geil, damit spiele ich heute mal rum! Danke!

 

[Trumpfi]

Es gibt mittlerweile eine Anwendung: Handbrake Batch (http://www.osomac.com/apps/osx/handbrake-batch/) die macht genau das was ich brauche. Einen sequentiellen Massenkonvert mit eine ausgewählten Std Preset.

Danke für den Link! Das ist auch genau was ich suchte. Nämlich ein Handbrake Automator Skript oder Batch um meine MKV Files aus einem Ordner zu konvertieren. Wirklich genial! Danke vielmals. Das nimmt mir einen Haufen Arbeit und Zeit ab. Werde auch an den Entwickler etwas spenden.

Liebe Grüße

Trumpfi