Automator – Namensteile des übergeordneten Ordners auslesen?

[DennisTheMenace79]

Hallo allerseits,
bin neu hier im Forum – und habe gleich ein Problem …
Ich versuche gerade mit Automator ein Programm zu erstellen, welches mir Dateien umbenennt:

1. Aktuelles Datum ans Ende setzen (E) – klappt
2. Unterstriche einfügen – klappt
3. Eine immer gleiche Bezeichnung vor den Dateinamen setzen (D) – klappt
4. Die Zeichen (A) im Ordnernamen bis zum ersten Leerschritt an den Anfang des Dateinamens setzen – klappt nicht :-(

So soll es in der Theorie funktionieren:

Vorher
Ordner: Zeichenkette(A) Zeichenkette(B)
Datei im Ordner: Zeichenkette(C)

Nachher
Ordner: Zeichenkette(A) Zeichenkette(B)
Datei im Ordner: Zeichenkette(A)_Zeichenkette(D)_Zeichenkette(C)_AktuellesDatum(E)

Wie lassen sich Teile des Ordnernamens auslesen? Automator stellt dafür keine Aktion bereit…
Läßt sich sowas mit Applescript realisieren?

Über etwas Hilfe würde ich mich sehr freuen.

Vielen Dank im Voraus.

 

[Pill]

Hi,

falls es noch aktuell sein sollte, hier ein AppleScript, dass du als App gespeichert entweder als Droplet oder per Doppelklick starten kannst:

-- Droplet:
on open (theFiles)
    renameFiles(theFiles)
end open

-- Programm:
on run
    set theFiles to choose file with multiple selections allowed
    renameFiles(theFiles)
end run

on renameFiles(theFiles)
    set theLabel to "Bezeichnung" -- Zeichenkette(D)
   
    tell application "Finder"
        repeat with aFile in theFiles
            set fileName to name of aFile
            set fileExtension to name extension of aFile
            set containerName to name of container of aFile
            set theDate to (current date)
            set dateString to day of theDate & "-" & (month of theDate as integer) & "-" & year of theDate
            set newName to first word of containerName & "_" & theLabel & "_" & text items 1 thru -((count (text items of fileExtension)) + 2) of fileName & "_" & dateString & "." & fileExtension
            set name of aFile to newName
        end repeat
    end tell
   
end renameFiles