Aktuelles TextEdit Dokument speichern?

[Psaniko]

hi,
ich hab ein problem, ich habe einen arbeitsablauf erstellt, der mehrmals nach text fragt und daraus dann eine textdatei macht.
Allerdings schaffe ich es nicht, dass der text am ende auch gespeichert wird.

Wenn ich den inhalt abfrage und den zu einem neuen dokument mache, kommt chinesische/japanische schrift?!?

weiß jemand eine lösung, meinetwegen auch mit AppleScript?

im voraus danke,

Psaniko

 

[little_pixel]

Hallo,

set pfadTargetFile to ((path to desktop) as text) & "MeinErgebnnis.txt" as file specification
set meineZeile to ""

-- Schleife für Eingaben, so lange bis Abbruch
repeat
	set meineZeile to text returned of (display dialog "Bitte um Eingabe:" default answer "überschreibe mich")
	my neuenDSschreiben(meineZeile, pfadTargetFile)
end repeat


--Funktion um neuen DS zu schreiben
on neuenDSschreiben(schreibeZeile, pfadTargetFile)
	try
		open for access pfadTargetFile with write permission
		write schreibeZeile & return to pfadTargetFile starting at eof
		close access pfadTargetFile
	on error
		try
			display dialog "Fehler beim Schreiben des aktuellen Datensatzes." with icon 0 giving up after 1
			close access pfadTargetFile
		end try
	end try
	
end neuenDSschreiben

Im Skripteditor öffnen und ausführen.

Viel Erfolg

 

[Psaniko]

erstmal danke für deine mühe,

aber da ich erst gestern angefangen hab, AppleScript zu lernen und noch nich so bewandert bin, weiß ich nich, wie ich dein script so verändere, dass nur 2 fragen kommen und dazwischen html text eingefügt wird.

Und kommt dann als ergebnis beim automator die textdatei?
Und nochwas: wie kann ich die dateiendung verändern?

wär nett, wenn du das noch hinzufügen könntest,

psaniko

 

[little_pixel]

Ich habe keine Ahnung von Automator
Mit AS kann man doch alles, für was brauche ich den

set pfadTargetFile to ((path to desktop) as text) & "startseite.html" as file specification
set meineZeile to ""

-- Schleife für Eingaben, so lange bis Abbruch
repeat 2 times
	set meineEingabe to text returned of (display dialog "Bitte um Eingabe:" default answer "überschreibe mich")
	set meineZeile to "<h1>" & meineEingabe & "</h1>"
	my neuenDSschreiben(meineZeile, pfadTargetFile)
end repeat


--Funktion um neuen DS zu schreiben
on neuenDSschreiben(schreibeZeile, pfadTargetFile)
	try
		open for access pfadTargetFile with write permission
		write schreibeZeile & return to pfadTargetFile starting at eof
		close access pfadTargetFile
	on error
		try
			display dialog "Fehler beim Schreiben des aktuellen Datensatzes." with icon 0 giving up after 1
			close access pfadTargetFile
		end try
	end try
	
end neuenDSschreiben

Viel Erfolg