Automator Hilfe: Datei-Umbenennung nach Quelle

[richarleo]

Hallo zusammen,

ich habe folgendes Problem:

ca 400 Dateien, die alle beliebige Titel haben. Ich möchte jeden dieser Titel durch einen Teil des bei jeder Datei in den Datei-Informationen unter "Quelle" gespeicherten Text ersetzen, der bei jeder Datei synonym ist.

Beispiel:
Datei a) heißt original-202.jpg. In der Dateiinfo ist ihre Quelle mit www.hans.de/28/02/009.jpg bezeichnet.
Datei b) heißt praxis.jpg, in der Dateiinfo ist die Quelle mit www.hans.de/29/02/010.jpg
-> Ich möchte erreichen, dass bei jeder Datei der Teil, der nach www.hans.de/ folgt, der neue Dateinamen wird.

Klingt finde ich kompliziert, zumindest geben es alle vorprogrammierten Scripts nicht her. Wer mir weiterhelfen kann wird in meine Gebete eingeschlossen, soviel ist sicher.

Grüße,
richarleo

 

[chebfarid]

Was meinst Du, wenn Du von "Quelle" in der Dateiinfo sprichst?
Im Finder? In meinem Finderinfo (Leopard 10.5.6) gibt es die Stimme nicht...
Kommt diese Information aus einem anderen Programm, z.B. Photoshop ?
Oder beziehst Du Dich auf den Spotlight-Kommentar?

Ciao
Farid

 

[richarleo]

hallo,

danke für deine Antwort. Also bei mir zeigt er die info "Quelle" bei manchen Dateien unter "Weitere Informationen" an. Aber auch nicht bei allen. Beispiel: Suche bei google nach Hans Arp und ziehe das erste Bild in deinen Desktop. Da steht dann die URL als "Quelle" in der Finder-Datei-Info.

Gruß,
richarleo

 

[chebfarid]

Das Umbenennen als solches ist kein Problem, aber das geht nicht mit Automator allein, da mußt Du schon AppleScript benutzen.

Der schwierige Teil ist, die Quelle aus dem Dateiinfo auszulesen, weil sich diese, wie ich nach einer Stunde suchen herausbekommen habe, nicht im File-Info und auch nicht im Bild-Info befindet, sondern in einem versteckten Archiv, das Spotlight für seine Indizierung benutzt. Diese Information kann man über ein Shellskript ansprechen und dann ist das Umbenennen ein Kinderspiel.
Bin jetzt unterwegs und die Batterie des MacBook Pro ist leer - heute abend mehr.

Ciao
Farid

 

[richarleo]

vielen dank! ich freue mich auf mehr...

 

[chebfarid]

Ich denke, so passt es:
(Das Skript als Anwendung speichern und einfach die Bildfiles draufziehen um Sie automatisch umzubenennen.)

-- Als Anwendung (Droplet) speichern und die Bilder draufziehen:
on open myFiles
	set otid to text item delimiters
	
	repeat with aFile in myFiles
		set posFile to quoted form of (POSIX path of aFile)
		-- shell script liest die Quelle aus dem Spotlightinfo heraus:
		set theInfo to (do shell script "mdls -name kMDItemWhereFroms " & posFile)
		
		set text item delimiters to "\""
		set theUrl to text item 2 of theInfo
		
		try
			set text item delimiters to "www.hans.de/" -- die InfoZeile wird nach 'www.hans.de/' getrennt
			set newName to text item 2 of theUrl -- der Rest wird der neue Filename
			
			tell application "Finder"
				set name of aFile to newName
			end tell
		end try
		
	end repeat
	set text item delimiters to otid
end open

Good scripting
Farid

 

[richarleo]

Vielen Dank, alles bestens!